nsz Git - musl/blob - src/setjmp/arm/longjmp.s

   1 .syntax unified
   2 .global _longjmp
   3 .global longjmp
   4 .type _longjmp,%function
   5 .type longjmp,%function
   6 _longjmp:
   7 longjmp:
   8         mov ip,r0
   9         movs r0,r1
  10         moveq r0,#1
  11         ldmia ip!, {v1,v2,v3,v4,v5,v6,sl,fp,sp,lr}
  12
  13         adr r1,1f
  14         ldr r2,1f
  15         ldr r1,[r1,r2]
  16
  17         tst r1,#0x260
  18         beq 3f
  19         tst r1,#0x20
  20         beq 2f
  21         ldc p2, cr4, [ip], #48
  22 2:      tst r1,#0x40
  23         beq 2f
  24         .fpu vfp
  25         vldmia ip!, {d8-d15}
  26         .fpu softvfp
  27         .eabi_attribute 10, 0
  28         .eabi_attribute 27, 0
  29 2:      tst r1,#0x200
  30         beq 3f
  31         ldcl p1, cr10, [ip], #8
  32         ldcl p1, cr11, [ip], #8
  33         ldcl p1, cr12, [ip], #8
  34         ldcl p1, cr13, [ip], #8
  35         ldcl p1, cr14, [ip], #8
  36         ldcl p1, cr15, [ip], #8
  37 3:      bx lr
  38
  39 .hidden __hwcap
  40 1:      .word __hwcap-1b