nsz Git - musl/blob - src/ldso/aarch64/tlsdesc.s

   1 // long __tlsdesc_static(long *a)
   2 // {
   3 //      return a[1];
   4 // }
   5 .global __tlsdesc_static
   6 .type __tlsdesc_static,@function
   7 __tlsdesc_static:
   8         ldr x0,[x0,#8]
   9         ret
  10
  11 .hidden __tls_get_new
  12
  13 // long __tlsdesc_dynamic(long *a)
  14 // {
  15 //      struct {size_t modidx,off;} *p = (void*)a[1];
  16 //      size_t *dtv = *(size_t**)(tp + 16 - 8);
  17 //      if (p->modidx <= dtv[0])
  18 //              return dtv[p->modidx] + p->off - tp;
  19 //      return __tls_get_addr(p) - tp;
  20 // }
  21 .global __tlsdesc_dynamic
  22 .type __tlsdesc_dynamic,@function
  23 __tlsdesc_dynamic:
  24         stp x1,x2,[sp,#-32]!
  25         stp x3,x4,[sp,#16]
  26         mrs x1,tpidr_el0      // tp
  27         ldr x0,[x0,#8]        // p
  28         ldr x2,[x0]           // p->modidx
  29         add x3,x1,#8
  30         ldr x3,[x3]           // dtv
  31         ldr x4,[x3]           // dtv[0]
  32         cmp x2,x4
  33         b.hi 1f
  34         ldr x2,[x3,x2,lsl #3] // dtv[p->modidx]
  35         ldr x0,[x0,#8]        // p->off
  36         add x0,x0,x2
  37 2:      sub x0,x0,x1
  38         ldp x3,x4,[sp,#16]
  39         ldp x1,x2,[sp],#32
  40         ret
  41
  42         // save all registers __tls_get_new may clobber
  43         // ugly because addr offset must be in [-512,509]
  44 1:      stp x29,x30,[sp,#-160]!
  45         stp x5,x6,[sp,#16]
  46         stp x7,x8,[sp,#32]
  47         stp x9,x10,[sp,#48]
  48         stp x11,x12,[sp,#64]
  49         stp x13,x14,[sp,#80]
  50         stp x15,x16,[sp,#96]
  51         stp x17,x18,[sp,#112]
  52         stp q0,q1,[sp,#128]
  53         stp q2,q3,[sp,#-480]!
  54         stp q4,q5,[sp,#32]
  55         stp q6,q7,[sp,#64]
  56         stp q8,q9,[sp,#96]
  57         stp q10,q11,[sp,#128]
  58         stp q12,q13,[sp,#160]
  59         stp q14,q15,[sp,#192]
  60         stp q16,q17,[sp,#224]
  61         stp q18,q19,[sp,#256]
  62         stp q20,q21,[sp,#288]
  63         stp q22,q23,[sp,#320]
  64         stp q24,q25,[sp,#352]
  65         stp q26,q27,[sp,#384]
  66         stp q28,q29,[sp,#416]
  67         stp q30,q31,[sp,#448]
  68         bl __tls_get_new
  69         mrs x1,tpidr_el0
  70         ldp q4,q5,[sp,#32]
  71         ldp q6,q7,[sp,#64]
  72         ldp q8,q9,[sp,#96]
  73         ldp q10,q11,[sp,#128]
  74         ldp q12,q13,[sp,#160]
  75         ldp q14,q15,[sp,#192]
  76         ldp q16,q17,[sp,#224]
  77         ldp q18,q19,[sp,#256]
  78         ldp q20,q21,[sp,#288]
  79         ldp q22,q23,[sp,#320]
  80         ldp q24,q25,[sp,#352]
  81         ldp q26,q27,[sp,#384]
  82         ldp q28,q29,[sp,#416]
  83         ldp q30,q31,[sp,#448]
  84         ldp q2,q3,[sp],#480
  85         ldp x5,x6,[sp,#16]
  86         ldp x7,x8,[sp,#32]
  87         ldp x9,x10,[sp,#48]
  88         ldp x11,x12,[sp,#64]
  89         ldp x13,x14,[sp,#80]
  90         ldp x15,x16,[sp,#96]
  91         ldp x17,x18,[sp,#112]
  92         ldp q0,q1,[sp,#128]
  93         ldp x29,x30,[sp],#160
  94         b 2b