nsz Git - musl/blob - src/ldso/aarch64/tlsdesc.s

   1 // size_t __tlsdesc_static(size_t *a)
   2 // {
   3 //      return a[1];
   4 // }
   5 .global __tlsdesc_static
   6 .hidden __tlsdesc_static
   7 .type __tlsdesc_static,@function
   8 __tlsdesc_static:
   9         ldr x0,[x0,#8]
  10         ret
  11
  12 .hidden __tls_get_new
  13
  14 // size_t __tlsdesc_dynamic(size_t *a)
  15 // {
  16 //      struct {size_t modidx,off;} *p = (void*)a[1];
  17 //      size_t *dtv = *(size_t**)(tp - 8);
  18 //      if (p->modidx <= dtv[0])
  19 //              return dtv[p->modidx] + p->off - tp;
  20 //      return __tls_get_new(p) - tp;
  21 // }
  22 .global __tlsdesc_dynamic
  23 .hidden __tlsdesc_dynamic
  24 .type __tlsdesc_dynamic,@function
  25 __tlsdesc_dynamic:
  26         stp x1,x2,[sp,#-32]!
  27         stp x3,x4,[sp,#16]
  28         mrs x1,tpidr_el0      // tp
  29         ldr x0,[x0,#8]        // p
  30         ldr x2,[x0]           // p->modidx
  31         ldr x3,[x1,#-8]       // dtv
  32         ldr x4,[x3]           // dtv[0]
  33         cmp x2,x4
  34         b.hi 1f
  35         ldr x2,[x3,x2,lsl #3] // dtv[p->modidx]
  36         ldr x0,[x0,#8]        // p->off
  37         add x0,x0,x2
  38 2:      sub x0,x0,x1
  39         ldp x3,x4,[sp,#16]
  40         ldp x1,x2,[sp],#32
  41         ret
  42
  43         // save all registers __tls_get_new may clobber
  44         // update sp in two steps because offset must be in [-512,509]
  45 1:      stp x29,x30,[sp,#-160]!
  46         stp x5,x6,[sp,#16]
  47         stp x7,x8,[sp,#32]
  48         stp x9,x10,[sp,#48]
  49         stp x11,x12,[sp,#64]
  50         stp x13,x14,[sp,#80]
  51         stp x15,x16,[sp,#96]
  52         stp x17,x18,[sp,#112]
  53         stp q0,q1,[sp,#128]
  54         stp q2,q3,[sp,#-480]!
  55         stp q4,q5,[sp,#32]
  56         stp q6,q7,[sp,#64]
  57         stp q8,q9,[sp,#96]
  58         stp q10,q11,[sp,#128]
  59         stp q12,q13,[sp,#160]
  60         stp q14,q15,[sp,#192]
  61         stp q16,q17,[sp,#224]
  62         stp q18,q19,[sp,#256]
  63         stp q20,q21,[sp,#288]
  64         stp q22,q23,[sp,#320]
  65         stp q24,q25,[sp,#352]
  66         stp q26,q27,[sp,#384]
  67         stp q28,q29,[sp,#416]
  68         stp q30,q31,[sp,#448]
  69         bl __tls_get_new
  70         mrs x1,tpidr_el0
  71         ldp q4,q5,[sp,#32]
  72         ldp q6,q7,[sp,#64]
  73         ldp q8,q9,[sp,#96]
  74         ldp q10,q11,[sp,#128]
  75         ldp q12,q13,[sp,#160]
  76         ldp q14,q15,[sp,#192]
  77         ldp q16,q17,[sp,#224]
  78         ldp q18,q19,[sp,#256]
  79         ldp q20,q21,[sp,#288]
  80         ldp q22,q23,[sp,#320]
  81         ldp q24,q25,[sp,#352]
  82         ldp q26,q27,[sp,#384]
  83         ldp q28,q29,[sp,#416]
  84         ldp q30,q31,[sp,#448]
  85         ldp q2,q3,[sp],#480
  86         ldp x5,x6,[sp,#16]
  87         ldp x7,x8,[sp,#32]
  88         ldp x9,x10,[sp,#48]
  89         ldp x11,x12,[sp,#64]
  90         ldp x13,x14,[sp,#80]
  91         ldp x15,x16,[sp,#96]
  92         ldp x17,x18,[sp,#112]
  93         ldp q0,q1,[sp,#128]
  94         ldp x29,x30,[sp],#160
  95         b 2b