nsz Git - musl/blob - src/ldso/aarch64/tlsdesc.s

   1 // long __tlsdesc_static(long *a)
   2 // {
   3 //      return a[1];
   4 // }
   5 .global __tlsdesc_static
   6 .type __tlsdesc_static,@function
   7 __tlsdesc_static:
   8         ldr x0,[x0,#8]
   9         ret
  10
  11 // long __tlsdesc_dynamic(long *a)
  12 // {
  13 //      struct {size_t modidx,off;} *p = (void*)a[1];
  14 //      size_t *dtv = *(size_t**)(tp + 16 - 8);
  15 //      if (p->modidx <= dtv[0])
  16 //              return dtv[p->modidx] + p->off - tp;
  17 //      return __tls_get_addr(p) - tp;
  18 // }
  19 .global __tlsdesc_dynamic
  20 .type __tlsdesc_dynamic,@function
  21 __tlsdesc_dynamic:
  22         stp x1,x2,[sp,#-32]!
  23         stp x3,x4,[sp,#16]
  24         mrs x1,tpidr_el0      // tp
  25         ldr x0,[x0,#8]        // p
  26         ldr x2,[x0]           // p->modidx
  27         add x3,x1,#8
  28         ldr x3,[x3]           // dtv
  29         ldr x4,[x3]           // dtv[0]
  30         cmp x2,x4
  31         b.hi 1f
  32         ldr x2,[x3,x2,lsl #3] // dtv[p->modidx]
  33         ldr x0,[x0,#8]        // p->off
  34         add x0,x0,x2
  35 2:      sub x0,x0,x1
  36         ldp x3,x4,[sp,#16]
  37         ldp x1,x2,[sp],#32
  38         ret
  39
  40         // save all registers __tls_get_addr may clobber
  41         // ugly because addr offset must be in [-512,509]
  42 1:      stp x29,x30,[sp,#-160]!
  43         stp x5,x6,[sp,#16]
  44         stp x7,x8,[sp,#32]
  45         stp x9,x10,[sp,#48]
  46         stp x11,x12,[sp,#64]
  47         stp x13,x14,[sp,#80]
  48         stp x15,x16,[sp,#96]
  49         stp x17,x18,[sp,#112]
  50         stp q0,q1,[sp,#128]
  51         stp q2,q3,[sp,#-480]!
  52         stp q4,q5,[sp,#32]
  53         stp q6,q7,[sp,#64]
  54         stp q8,q9,[sp,#96]
  55         stp q10,q11,[sp,#128]
  56         stp q12,q13,[sp,#160]
  57         stp q14,q15,[sp,#192]
  58         stp q16,q17,[sp,#224]
  59         stp q18,q19,[sp,#256]
  60         stp q20,q21,[sp,#288]
  61         stp q22,q23,[sp,#320]
  62         stp q24,q25,[sp,#352]
  63         stp q26,q27,[sp,#384]
  64         stp q28,q29,[sp,#416]
  65         stp q30,q31,[sp,#448]
  66         bl __tls_get_addr
  67         mrs x1,tpidr_el0
  68         ldp q4,q5,[sp,#32]
  69         ldp q6,q7,[sp,#64]
  70         ldp q8,q9,[sp,#96]
  71         ldp q10,q11,[sp,#128]
  72         ldp q12,q13,[sp,#160]
  73         ldp q14,q15,[sp,#192]
  74         ldp q16,q17,[sp,#224]
  75         ldp q18,q19,[sp,#256]
  76         ldp q20,q21,[sp,#288]
  77         ldp q22,q23,[sp,#320]
  78         ldp q24,q25,[sp,#352]
  79         ldp q26,q27,[sp,#384]
  80         ldp q28,q29,[sp,#416]
  81         ldp q30,q31,[sp,#448]
  82         ldp q2,q3,[sp],#480
  83         ldp x5,x6,[sp,#16]
  84         ldp x7,x8,[sp,#32]
  85         ldp x9,x10,[sp,#48]
  86         ldp x11,x12,[sp,#64]
  87         ldp x13,x14,[sp,#80]
  88         ldp x15,x16,[sp,#96]
  89         ldp x17,x18,[sp,#112]
  90         ldp q0,q1,[sp,#128]
  91         ldp x29,x30,[sp],#160
  92         b 2b