nsz Git - musl/blob - src/ldso/aarch64/tlsdesc.s

   1 // size_t __tlsdesc_static(size_t *a)
   2 // {
   3 //      return a[1];
   4 // }
   5 .global __tlsdesc_static
   6 .hidden __tlsdesc_static
   7 .type __tlsdesc_static,@function
   8 __tlsdesc_static:
   9         ldr x0,[x0,#8]
  10         ret
  11
  12 .hidden __tls_get_new
  13
  14 // size_t __tlsdesc_dynamic(size_t *a)
  15 // {
  16 //      struct {size_t modidx,off;} *p = (void*)a[1];
  17 //      size_t *dtv = *(size_t**)(tp - 8);
  18 //      if (p->modidx <= dtv[0])
  19 //              return dtv[p->modidx] + p->off - tp;
  20 //      return __tls_get_new(p) - tp;
  21 // }
  22 .global __tlsdesc_dynamic
  23 .hidden __tlsdesc_dynamic
  24 .type __tlsdesc_dynamic,@function
  25 __tlsdesc_dynamic:
  26         stp x1,x2,[sp,#-32]!
  27         stp x3,x4,[sp,#16]
  28         mrs x1,tpidr_el0      // tp
  29         ldr x0,[x0,#8]        // p
  30         ldr x2,[x0]           // p->modidx
  31         ldr x3,[x1,#-8]       // dtv
  32         ldr x2,[x3,x2,lsl #3] // dtv[p->modidx]
  33         ldr x0,[x0,#8]        // p->off
  34         add x0,x0,x2
  35         sub x0,x0,x1
  36         ldp x3,x4,[sp,#16]
  37         ldp x1,x2,[sp],#32
  38         ret