nsz Git - musl/blob - src/ldso/aarch64/tlsdesc.s

   1 // size_t __tlsdesc_static(size_t *a)
   2 // {
   3 //      return a[1];
   4 // }
   5 .global __tlsdesc_static
   6 .hidden __tlsdesc_static
   7 .type __tlsdesc_static,@function
   8 __tlsdesc_static:
   9         ldr x0,[x0,#8]
  10         ret
  11
  12 .hidden __tls_get_new
  13
  14 // size_t __tlsdesc_dynamic(size_t *a)
  15 // {
  16 //      struct {size_t modidx,off;} *p = (void*)a[1];
  17 //      size_t *dtv = *(size_t**)(tp - 8);
  18 //      if (p->modidx <= dtv[0])
  19 //              return dtv[p->modidx] + p->off - tp;
  20 //      return __tls_get_new(p) - tp;
  21 // }
  22 .global __tlsdesc_dynamic
  23 .hidden __tlsdesc_dynamic
  24 .type __tlsdesc_dynamic,@function
  25 __tlsdesc_dynamic:
  26         stp x1,x2,[sp,#-16]!
  27         mrs x1,tpidr_el0      // tp
  28         ldr x0,[x0,#8]        // p
  29         ldp x0,x2,[x0]        // p->modidx, p->off
  30         sub x2,x2,x1          // p->off - tp
  31         ldr x1,[x1,#-8]       // dtv
  32         ldr x1,[x1,x0,lsl #3] // dtv[p->modidx]
  33         add x0,x1,x2          // dtv[p->modidx] + p->off - tp
  34         ldp x1,x2,[sp],#16
  35         ret