X-Git-Url: http://nsz.repo.hu/git/?p=musl;a=blobdiff_plain;f=src%2Finternal%2Fi386%2Fsyscall.s;h=291168c3240b55007132d4d479936b378d22fd78;hp=5b19a1b86cc8a8cd38fd713ce6650116f647c856;hb=216dca82f6948627f55a0a04ab7d63a12213d8ed;hpb=d00ff2950eacc375d57e44d65c7697f636c67625

diff --git a/src/internal/i386/syscall.s b/src/internal/i386/syscall.s
index 5b19a1b8..291168c3 100644
--- a/src/internal/i386/syscall.s
+++ b/src/internal/i386/syscall.s
@@ -1,21 +1,74 @@
+.hidden __sysinfo
+
+# The calling convention for __vsyscall has the syscall number
+# and 5 args arriving as:  eax, edx, ecx, edi, esi, 4(%esp).
+# This ensures that the inline asm in the C code never has to touch
+# ebx or ebp (which are unavailable in PIC and frame-pointer-using
+# code, respectively), and optimizes for size/simplicity in the caller.
+
+.global __vsyscall
+.type __vsyscall,@function
+__vsyscall:
+	push %edi
+	push %ebx
+	mov %edx,%ebx
+	mov %edi,%edx
+	mov 12(%esp),%edi
+	push %eax
+	call 1f
+2:	pop %ebx
+	pop %ebx
+	pop %edi
+	ret
+
+1:	mov (%esp),%eax
+	add $[__sysinfo-2b],%eax
+	mov (%eax),%eax
+	test %eax,%eax
+	jz 1f
+	push %eax
+	mov 8(%esp),%eax
+	ret                     # tail call to kernel vsyscall entry
+1:	mov 4(%esp),%eax
+	int $128
+	ret
+
+# The __vsyscall6 entry point is used only for 6-argument syscalls.
+# Instead of passing the 5th argument on the stack, a pointer to the
+# 5th and 6th arguments is passed. This is ugly, but there are no
+# register constraints the inline asm could use that would make it
+# possible to pass two arguments on the stack.
+
+.global __vsyscall6
+.type __vsyscall6,@function
+__vsyscall6:
+	push %ebp
+	push %eax
+	mov 12(%esp), %ebp
+	mov (%ebp), %eax
+	mov 4(%ebp), %ebp
+	push %eax
+	mov 4(%esp),%eax
+	call __vsyscall
+	pop %ebp
+	pop %ebp
+	pop %ebp
+	ret
+
 .global __syscall
-.type __syscall,%function
+.type __syscall,@function
 __syscall:
-	pushl %ebx
-	pushl %esi
-	pushl %edi
-	pushl %ebp
-	movl 20(%esp),%eax
-	movl 24(%esp),%ebx
-	movl 28(%esp),%ecx
-	movl 32(%esp),%edx
-	movl 36(%esp),%esi
-	movl 40(%esp),%edi
-	movl 44(%esp),%ebp
-	int $128
-	popl %ebp
-	popl %edi
-	popl %esi
-	popl %ebx
+	lea 24(%esp),%eax
+	push %esi
+	push %edi
+	push %eax
+	mov 16(%esp),%eax
+	mov 20(%esp),%edx
+	mov 24(%esp),%ecx
+	mov 28(%esp),%edi
+	mov 32(%esp),%esi
+	call __vsyscall6
+	pop %edi
+	pop %edi
+	pop %esi
 	ret
-.size __syscall,.-__syscall