nsz Git - musl/blob - src/setjmp/powerpc/longjmp.s

   1         .global _longjmp
   2         .global longjmp
   3         .type   _longjmp,@function
   4         .type   longjmp,@function
   5 _longjmp:
   6 longjmp:
   7 # void longjmp(jmp_buf env, int val);
   8 # put val into return register and restore the env saved in setjmp
   9 # if val(r4) is 0, put 1 there.
  10         # 0) move old return address into r0
  11         lwz 0, 0(3)
  12         # 1) put it into link reg
  13         mtlr 0
  14         #2 ) restore stack ptr
  15         lwz 1, 4(3)
  16         #3) restore control reg
  17         lwz 0, 8(3)
  18         mtcr 0
  19         #4) restore r14-r31
  20         lwz 14, 12(3)
  21         lwz 15, 16(3)
  22         lwz 16, 20(3)
  23         lwz 17, 24(3)
  24         lwz 18, 28(3)
  25         lwz 19, 32(3)
  26         lwz 20, 36(3)
  27         lwz 21, 40(3)
  28         lwz 22, 44(3)
  29         lwz 23, 48(3)
  30         lwz 24, 52(3)
  31         lwz 25, 56(3)
  32         lwz 26, 60(3)
  33         lwz 27, 64(3)
  34         lwz 28, 68(3)
  35         lwz 29, 72(3)
  36         lwz 30, 76(3)
  37         lwz 31, 80(3)
  38         #5) put val into return reg r3
  39         mr 3, 4
  40
  41         #6) check if return value is 0, make it 1 in that case
  42         cmpwi cr7, 4, 0
  43         bne cr7, 1f
  44         li 3, 1
  45 1:
  46         blr
  47