nsz Git - libfirm/blob - configure.ac

   1 dnl
   2 dnl Project:     libFIRM
   3 dnl File name:   configure.in
   4 dnl Purpose:
   5 dnl Author:      Matthias Braun
   6 dnl CVS-ID:      $Id$
   7 dnl Copyright:   (c) 2002-2007 University of Karlsruhe
   8 dnl Licence:     This file protected by GPL -  GNU GENERAL PUBLIC LICENSE.
   9 dnl
  10 AC_PREREQ([2.54])
  11 AC_REVISION([$Id$])
  12 m4_define([firm_major_version], [1])
  13 m4_define([firm_minor_version], [14])
  14 m4_define([firm_micro_version], [0])
  15 m4_define([firm_version],
  16           [firm_major_version.firm_minor_version.firm_micro_version])
  17 AC_INIT([libfirm], [firm_version], [firm@ipd.info.uni-karlsruhe.de])
  18 AC_CONFIG_SRCDIR([ir/common/firm.c])
  19 AM_INIT_AUTOMAKE([foreign dist-bzip2 1.9])
  20
  21 # see libtool manual on what version numbers mean!
  22 LT_VERSION=0:0:0
  23 AC_SUBST([LT_VERSION])
  24
  25 AC_DEFINE([libfirm_VERSION_MAJOR], [firm_major_version], [Firms major version number])
  26 AC_DEFINE([libfirm_VERSION_MINOR], [firm_minor_version], [Firms minor version number])
  27 AC_DEFINE([libfirm_VERSION_MICRO], [firm_micro_version], [Firms micro version number])
  28
  29 dnl generate the config header file
  30 AC_CONFIG_HEADER([config.h])
  31
  32 dnl keep track of the environment set by the user
  33 libfirm_conf_env="${CC+CC='$CC'} ${CFLAGS+CFLAGS='$CFLAGS'} ${CPP+CPP='$CPP'} ${CPPFLAGS+CPPFLAGS='$CPPFLAGS'} ${LDFLAGS+LDFLAGS='$LDFLAGS'} ${LIBS+LIBS='$LIBS'}"
  34 AC_SUBST(libfirm_conf_env)
  35
  36 dnl Package options
  37 dnl ===============
  38
  39 dnl check for additional include dirs
  40 AC_ARG_WITH(includedir, [  --with-includedir=add   colon seperated list of directories to include search path],
  41     CPPFLAGS=$CPPFLAGS" -I"`echo $withval|sed 's;\:; -I;g'`)
  42
  43 dnl check for additional library dirs
  44 AC_ARG_WITH(libdir, [  --with-libdir=add       colon seperated list of directories to linker search path],
  45     LDFLAGS=$LDFLAGS" -L"`echo $withval|sed 's;\:; -L;g'`)
  46
  47 dnl set debugging
  48 dnl -------------
  49 AC_ARG_ENABLE([debug],
  50 [AS_HELP_STRING([--disable-debug], [disable verifiers and additional debugging routines])],
  51 [enable_debug_libfirm="$enableval"], [enable_debug_libfirm="yes"])
  52 if test "$enable_debug_libfirm" = yes; then
  53         AC_DEFINE([DEBUG_libfirm], [], [define to enable debug mode and checks])
  54 fi
  55
  56 AC_ARG_ENABLE([assert],
  57 [AS_HELP_STRING([--disable-assert], [disable assertions])],
  58 [enable_assert="$enableval"], [enable_assert="yes"])
  59 if test "$enable_assert" = no; then
  60   AC_DEFINE([NDEBUG], [], [define to disable asserts])
  61 fi
  62 AC_SUBST([enable_assert])
  63
  64 dnl set profiling
  65 dnl -------------
  66 AC_ARG_ENABLE([profile],
  67 [AS_HELP_STRING([--enable-profile], [enable profiling])],
  68 [enable_profile_libfirm="$enableval"], [enable_profile_libfirm="no"])
  69
  70 AC_SUBST([enable_profile_libfirm])
  71
  72 dnl enable Firm statistics
  73 dnl -------------
  74 AC_ARG_ENABLE([statistics],
  75 [AS_HELP_STRING([--enable-statistics], [enable Firm statistics])],
  76 [enable_statistics="$enableval"], [enable_statistics="yes"])
  77
  78 if test "$enable_statistics" = yes; then
  79         FIRMCONFIG_FIRM_STATISTICS="#define FIRMCONFIG_FIRM_STATISTICS"
  80 fi
  81 AC_SUBST([FIRMCONFIG_FIRM_STATISTICS])
  82 AC_SUBST([enable_statistics])
  83
  84 dnl enable ILP solver support
  85 dnl --------------------------------
  86 AC_ARG_ENABLE([ilp],
  87 [AS_HELP_STRING([--enable-ilp], [enable ilp solver])],
  88 [enable_ilp="$enableval"], [enable_ilp="no"])
  89
  90 if test "$enable_ilp" = yes; then
  91   FIRMCONFIG_WITH_ILP="#define FIRMCONFIG_WITH_ILP"
  92   AC_DEFINE([WITH_ILP], [], [enable to build code using ilp solvers])
  93 fi
  94
  95 dnl disable backend
  96 dnl ---------------
  97 AC_ARG_ENABLE([backend],
  98 [AS_HELP_STRING([--disable-backend], [disable backends])],
  99 [enable_backend="$enableval"], [enable_backend="yes"])
 100
 101 AC_SUBST(enable_backend)
 102
 103 dnl Checks for programs.
 104 dnl ====================
 105
 106 dnl check for a C compiler
 107 dnl ----------------------
 108 AC_PROG_CC
 109 AC_PROG_LIBTOOL
 110
 111 AC_PATH_PROGS(PERL, perl perl5)
 112
 113 dnl check for awk
 114 dnl -------------
 115 AC_PROG_AWK
 116
 117 dnl Checks for header files.
 118 dnl ========================
 119
 120 AC_HEADER_STDC
 121 AC_CHECK_HEADERS([math.h], , AC_MSG_ERROR("math header file not found"))
 122
 123 dnl Checks for libraries.
 124 dnl =====================
 125
 126 AC_CHECK_LIB(m, main, ac_m_library="yes", ac_m_library="no")
 127 if test "$ac_m_library" != yes; then
 128   dnl std math library not found.
 129   AC_MSG_ERROR("standard math library not found")
 130 fi
 131
 132 dnl Checks for typedefs, structures, and compiler characteristics.
 133 dnl ==============================================================
 134 AC_C_CONST
 135 AC_C_VOLATILE
 136 AC_C_INLINE
 137 AC_C_BIGENDIAN(,,,)
 138 AC_C_LONG_DOUBLE
 139
 140 dnl Checks for library functions.
 141 dnl =============================
 142
 143 dnl check for strerror
 144
 145 AC_CHECK_FUNC(strerror,,
 146   AC_MSG_ERROR("need strerror function")
 147 )
 148
 149 dnl we use the gnu extension obstack_printf
 150 AC_DEFINE([_GNU_SOURCE], [], [we use gnu extensions])
 151 AC_CHECK_FUNC(strerror,,
 152   AC_MSG_ERROR("need obstack_printf function")
 153 )
 154
 155 dnl Error messaging
 156 dnl ===============
 157
 158
 159 dnl Output results
 160 AC_CONFIG_FILES([
 161         Makefile
 162         ir/Makefile
 163         include/libfirm/Makefile
 164         libfirm.pc
 165 ])
 166
 167 #always do inlining
 168 AC_DEFINE([INLINE], [inline], [define inline to compiler inline keyword])
 169
 170 BACKENDS=""
 171 if test "$enable_backend" = yes; then
 172         BACKENDS="arm ia32 mips ppc32"
 173 fi
 174 AC_SUBST([BACKENDS])
 175
 176 AC_OUTPUT
 177
 178 dnl output summary of firm configuration
 179 echo ""
 180 echo "firm configuration summary:"
 181 echo "     backends              $BACKENDS"
 182 echo "     profiling             $enable_profile_libfirm"
 183 echo "     debug/verifiers       $enable_debug_libfirm"
 184 echo "     assertions            $enable_assert"
 185 echo "     statistics            $enable_statistics"
 186 echo "     ilp                   $enable_ilp"
 187 echo ""