nsz Git - libfirm/blob - configure.ac

   1 dnl
   2 dnl Project:     libFIRM
   3 dnl File name:   configure.in
   4 dnl Purpose:
   5 dnl Author:      Matthias Braun
   6 dnl CVS-ID:      $Id$
   7 dnl Copyright:   (c) 2002-2007 University of Karlsruhe
   8 dnl Licence:     This file protected by GPL -  GNU GENERAL PUBLIC LICENSE.
   9 dnl
  10 AC_PREREQ([2.54])
  11 AC_REVISION([$Id$])
  12 m4_define([firm_major_version], [1])
  13 m4_define([firm_minor_version], [18])
  14 m4_define([firm_micro_version], [1])
  15 m4_define([firm_version],
  16           [firm_major_version.firm_minor_version.firm_micro_version])
  17 AC_INIT([libfirm], [firm_version], [firm@ipd.info.uni-karlsruhe.de])
  18 AC_CONFIG_SRCDIR([ir/common/firm.c])
  19 AM_INIT_AUTOMAKE([foreign dist-bzip2 1.9])
  20
  21 # see libtool manual on what version numbers mean!
  22 LT_VERSION=0:0:0
  23 AC_SUBST([LT_VERSION])
  24
  25 AC_DEFINE([libfirm_VERSION_MAJOR], [firm_major_version], [Firms major version number])
  26 AC_DEFINE([libfirm_VERSION_MINOR], [firm_minor_version], [Firms minor version number])
  27 AC_DEFINE([libfirm_VERSION_MICRO], [firm_micro_version], [Firms micro version number])
  28
  29 dnl enable libtool
  30 LT_INIT([win32-dll])
  31
  32 dnl generate the config header file
  33 AC_CONFIG_HEADER([config.h])
  34
  35 dnl keep track of the environment set by the user
  36 libfirm_conf_env="${CC+CC='$CC'} ${CFLAGS+CFLAGS='$CFLAGS'} ${CPP+CPP='$CPP'} ${CPPFLAGS+CPPFLAGS='$CPPFLAGS'} ${LDFLAGS+LDFLAGS='$LDFLAGS'} ${LIBS+LIBS='$LIBS -lm'}"
  37 AC_SUBST(libfirm_conf_env)
  38
  39 dnl enable visibility hidden
  40 CFLAGS="-fvisibility=hidden"
  41 AC_DEFINE([FIRM_BUILD_DLL], [], [Define when firm library is built])
  42
  43 dnl Package options
  44 dnl ===============
  45
  46 dnl check for additional include dirs
  47 AC_ARG_WITH(includedir, [  --with-includedir=add   colon seperated list of directories to include search path],
  48     CPPFLAGS=$CPPFLAGS" -I"`echo $withval|sed 's;\:; -I;g'`)
  49
  50 dnl check for additional library dirs
  51 AC_ARG_WITH(libdir, [  --with-libdir=add       colon seperated list of directories to linker search path],
  52     LDFLAGS=$LDFLAGS" -L"`echo $withval|sed 's;\:; -L;g'`)
  53
  54 dnl set debugging
  55 dnl -------------
  56 AC_ARG_ENABLE([debug],
  57 [AS_HELP_STRING([--disable-debug], [disable verifiers and additional debugging routines])],
  58 [enable_debug_libfirm="$enableval"], [enable_debug_libfirm="yes"])
  59 if test "$enable_debug_libfirm" = yes; then
  60         AC_DEFINE([DEBUG_libfirm], [], [define to enable debug mode and checks])
  61 fi
  62
  63 AC_ARG_ENABLE([assert],
  64 [AS_HELP_STRING([--disable-assert], [disable assertions])],
  65 [enable_assert="$enableval"], [enable_assert="yes"])
  66 if test "$enable_assert" = no; then
  67   AC_DEFINE([NDEBUG], [], [define to disable asserts])
  68 fi
  69 AC_SUBST([enable_assert])
  70
  71 dnl set profiling
  72 dnl -------------
  73 AC_ARG_ENABLE([profile],
  74 [AS_HELP_STRING([--enable-profile], [enable profiling])],
  75 [enable_profile_libfirm="$enableval"], [enable_profile_libfirm="no"])
  76
  77 AC_SUBST([enable_profile_libfirm])
  78
  79 dnl enable Firm statistics
  80 dnl -------------
  81 AC_ARG_ENABLE([statistics],
  82 [AS_HELP_STRING([--enable-statistics], [enable Firm statistics])],
  83 [enable_statistics="$enableval"], [enable_statistics="yes"])
  84
  85 if test "$enable_statistics" = yes; then
  86         FIRMCONFIG_FIRM_STATISTICS="#define FIRMCONFIG_FIRM_STATISTICS"
  87 fi
  88 AC_SUBST([FIRMCONFIG_FIRM_STATISTICS])
  89 AC_SUBST([enable_statistics])
  90
  91 dnl enable ILP solver support
  92 dnl --------------------------------
  93 AC_ARG_ENABLE([ilp],
  94 [AS_HELP_STRING([--enable-ilp], [enable ilp solver])],
  95 [enable_ilp="$enableval"], [enable_ilp="no"])
  96
  97 if test "$enable_ilp" = yes; then
  98   FIRMCONFIG_WITH_ILP="#define FIRMCONFIG_WITH_ILP"
  99   AC_DEFINE([WITH_ILP], [], [enable to build code using ilp solvers])
 100 fi
 101
 102 dnl disable backend
 103 dnl ---------------
 104 AC_ARG_ENABLE([backend],
 105 [AS_HELP_STRING([--disable-backend], [disable backends])],
 106 [enable_backend="$enableval"], [enable_backend="yes"])
 107
 108 AC_SUBST(enable_backend)
 109
 110 dnl Checks for programs.
 111 dnl ====================
 112
 113 dnl check for a C compiler
 114 dnl ----------------------
 115 AC_PROG_CC
 116
 117 AC_PATH_PROGS(PERL, perl perl5)
 118
 119 dnl check for awk
 120 dnl -------------
 121 AC_PROG_AWK
 122
 123 dnl Checks for header files.
 124 dnl ========================
 125
 126 AC_HEADER_STDC
 127 AC_CHECK_HEADERS([math.h], , AC_MSG_ERROR("math header file not found"))
 128 AC_CHECK_HEADERS([alloca.h])
 129
 130 dnl Checks for libraries.
 131 dnl =====================
 132
 133 AC_CHECK_LIB(m, main, ac_m_library="yes", ac_m_library="no")
 134 if test "$ac_m_library" != yes; then
 135   dnl std math library not found.
 136   AC_MSG_ERROR("standard math library not found")
 137 fi
 138
 139 dnl Checks for typedefs, structures, and compiler characteristics.
 140 dnl ==============================================================
 141 AC_C_CONST
 142 AC_C_VOLATILE
 143 AC_C_INLINE
 144 AC_C_BIGENDIAN(,,,)
 145 AC_C_LONG_DOUBLE
 146
 147 dnl Checks for library functions.
 148 dnl =============================
 149
 150 AC_FUNC_STRTOLD
 151
 152 dnl Error messaging
 153 dnl ===============
 154
 155
 156 dnl Output results
 157 AC_CONFIG_FILES([
 158         Makefile
 159         ir/Makefile
 160         include/libfirm/Makefile
 161         libfirm.pc
 162 ])
 163
 164 #always do inlining
 165 AC_DEFINE([INLINE], [inline], [define inline to compiler inline keyword])
 166
 167 BACKENDS=""
 168 if test "$enable_backend" = yes; then
 169         BACKENDS="arm ia32 mips ppc32 sparc amd64"
 170 fi
 171 AC_SUBST([BACKENDS])
 172
 173 AC_OUTPUT
 174
 175 dnl output summary of firm configuration
 176 echo ""
 177 echo "firm configuration summary:"
 178 echo "     backends              $BACKENDS"
 179 echo "     profiling             $enable_profile_libfirm"
 180 echo "     debug/verifiers       $enable_debug_libfirm"
 181 echo "     assertions            $enable_assert"
 182 echo "     statistics            $enable_statistics"
 183 echo "     ilp                   $enable_ilp"
 184 echo ""