nsz Git - libfirm/blob - acinclude.m4

   1 # pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
   2 #
   3 # Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18 #
  19 # As a special exception to the GNU General Public License, if you
  20 # distribute this file as part of a program that contains a
  21 # configuration script generated by Autoconf, you may include it under
  22 # the same distribution terms that you use for the rest of that program.
  23
  24 # PKG_PROG_PKG_CONFIG([MIN-VERSION])
  25 # ----------------------------------
  26 AC_DEFUN([PKG_PROG_PKG_CONFIG],
  27 [m4_pattern_forbid([^_?PKG_[A-Z_]+$])
  28 m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
  29 AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
  30 if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
  31         AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
  32 fi
  33 if test -n "$PKG_CONFIG"; then
  34         _pkg_min_version=m4_default([$1], [0.9.0])
  35         AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
  36         if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
  37                 AC_MSG_RESULT([yes])
  38         else
  39                 AC_MSG_RESULT([no])
  40                 PKG_CONFIG=""
  41         fi
  42
  43 fi[]dnl
  44 ])# PKG_PROG_PKG_CONFIG
  45
  46 # PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  47 #
  48 # Check to see whether a particular set of modules exists.  Similar
  49 # to PKG_CHECK_MODULES(), but does not set variables or print errors.
  50 #
  51 #
  52 # Similar to PKG_CHECK_MODULES, make sure that the first instance of
  53 # this or PKG_CHECK_MODULES is called, or make sure to call
  54 # PKG_CHECK_EXISTS manually
  55 # --------------------------------------------------------------
  56 AC_DEFUN([PKG_CHECK_EXISTS],
  57 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
  58 if test -n "$PKG_CONFIG" && \
  59     AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
  60   m4_ifval([$2], [$2], [:])
  61 m4_ifvaln([$3], [else
  62   $3])dnl
  63 fi])
  64
  65
  66 # _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
  67 # ---------------------------------------------
  68 m4_define([_PKG_CONFIG],
  69 [if test -n "$PKG_CONFIG"; then
  70     if test -n "$$1"; then
  71         pkg_cv_[]$1="$$1"
  72     else
  73         PKG_CHECK_EXISTS([$3],
  74                          [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
  75                          [pkg_failed=yes])
  76     fi
  77 else
  78         pkg_failed=untried
  79 fi[]dnl
  80 ])# _PKG_CONFIG
  81
  82 # _PKG_SHORT_ERRORS_SUPPORTED
  83 # -----------------------------
  84 AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
  85 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])
  86 if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
  87         _pkg_short_errors_supported=yes
  88 else
  89         _pkg_short_errors_supported=no
  90 fi[]dnl
  91 ])# _PKG_SHORT_ERRORS_SUPPORTED
  92
  93
  94 # PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
  95 # [ACTION-IF-NOT-FOUND])
  96 #
  97 #
  98 # Note that if there is a possibility the first call to
  99 # PKG_CHECK_MODULES might not happen, you should be sure to include an
 100 # explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
 101 #
 102 #
 103 # --------------------------------------------------------------
 104 AC_DEFUN([PKG_CHECK_MODULES],
 105 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 106 AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
 107 AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
 108
 109 pkg_failed=no
 110 AC_MSG_CHECKING([for $1])
 111
 112 _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
 113 _PKG_CONFIG([$1][_LIBS], [libs], [$2])
 114
 115 m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
 116 and $1[]_LIBS to avoid the need to call pkg-config.
 117 See the pkg-config man page for more details.])
 118
 119 if test $pkg_failed = yes; then
 120         _PKG_SHORT_ERRORS_SUPPORTED
 121         if test $_pkg_short_errors_supported = yes; then
 122                 $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --errors-to-stdout --print-errors "$2"`
 123         else
 124                 $1[]_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 125         fi
 126         # Put the nasty error message in config.log where it belongs
 127         echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
 128
 129         ifelse([$4], , [AC_MSG_ERROR(dnl
 130 [Package requirements ($2) were not met:
 131
 132 $$1_PKG_ERRORS
 133
 134 Consider adjusting the PKG_CONFIG_PATH environment variable if you
 135 installed software in a non-standard prefix.
 136
 137 _PKG_TEXT
 138 ])],
 139                 [$4])
 140 elif test $pkg_failed = untried; then
 141         ifelse([$4], , [AC_MSG_FAILURE(dnl
 142 [The pkg-config script could not be found or is too old.  Make sure it
 143 is in your PATH or set the PKG_CONFIG environment variable to the full
 144 path to pkg-config.
 145
 146 _PKG_TEXT
 147
 148 To get pkg-config, see <http://www.freedesktop.org/software/pkgconfig>.])],
 149                 [$4])
 150 else
 151         $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
 152         $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
 153         AC_MSG_RESULT([yes])
 154         ifelse([$3], , :, [$3])
 155 fi[]dnl
 156 ])# PKG_CHECK_MODULES
 157
 158 # ===========================================================================
 159 #   http://www.gnu.org/software/autoconf-archive/ax_cflags_gcc_option.html
 160 # ===========================================================================
 161 #
 162 # SYNOPSIS
 163 #
 164 #   AX_CFLAGS_GCC_OPTION (optionflag [,[shellvar][,[A][,[NA]]])
 165 #
 166 # DESCRIPTION
 167 #
 168 #   AX_CFLAGS_GCC_OPTION(-fvomit-frame) would show a message as like
 169 #   "checking CFLAGS for gcc -fvomit-frame ... yes" and adds the optionflag
 170 #   to CFLAGS if it is understood. You can override the shellvar-default of
 171 #   CFLAGS of course. The order of arguments stems from the explicit macros
 172 #   like AX_CFLAGS_WARN_ALL.
 173 #
 174 #   The cousin AX_CXXFLAGS_GCC_OPTION would check for an option to add to
 175 #   CXXFLAGS - and it uses the autoconf setup for C++ instead of C (since it
 176 #   is possible to use different compilers for C and C++).
 177 #
 178 #   The macro is a lot simpler than any special AX_CFLAGS_* macro (or
 179 #   ax_cxx_rtti.m4 macro) but allows to check for arbitrary options.
 180 #   However, if you use this macro in a few places, it would be great if you
 181 #   would make up a new function-macro and submit it to the ac-archive.
 182 #
 183 #     - $1 option-to-check-for : required ("-option" as non-value)
 184 #     - $2 shell-variable-to-add-to : CFLAGS (or CXXFLAGS in the other case)
 185 #     - $3 action-if-found : add value to shellvariable
 186 #     - $4 action-if-not-found : nothing
 187 #
 188 #   Note: in earlier versions, $1-$2 were swapped. We try to detect the
 189 #   situation and accept a $2=~/-/ as being the old option-to-check-for.
 190 #
 191 #   There are other variants that emerged from the original macro variant
 192 #   which did just test an option to be possibly added. However, some
 193 #   compilers accept an option silently, or possibly for just another option
 194 #   that was not intended. Therefore, we have to do a generic test for a
 195 #   compiler family. For gcc we check "-pedantic" being accepted which is
 196 #   also understood by compilers who just want to be compatible with gcc
 197 #   even when not being made from gcc sources.
 198 #
 199 #   See also: AX_CFLAGS_SUN_OPTION, AX_CFLAGS_HPUX_OPTION,
 200 #   AX_CFLAGS_AIX_OPTION, and AX_CFLAGS_IRIX_OPTION.
 201 #
 202 # LICENSE
 203 #
 204 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
 205 #
 206 #   This program is free software; you can redistribute it and/or modify it
 207 #   under the terms of the GNU General Public License as published by the
 208 #   Free Software Foundation; either version 2 of the License, or (at your
 209 #   option) any later version.
 210 #
 211 #   This program is distributed in the hope that it will be useful, but
 212 #   WITHOUT ANY WARRANTY; without even the implied warranty of
 213 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
 214 #   Public License for more details.
 215 #
 216 #   You should have received a copy of the GNU General Public License along
 217 #   with this program. If not, see <http://www.gnu.org/licenses/>.
 218 #
 219 #   As a special exception, the respective Autoconf Macro's copyright owner
 220 #   gives unlimited permission to copy, distribute and modify the configure
 221 #   scripts that are the output of Autoconf when processing the Macro. You
 222 #   need not follow the terms of the GNU General Public License when using
 223 #   or distributing such scripts, even though portions of the text of the
 224 #   Macro appear in them. The GNU General Public License (GPL) does govern
 225 #   all other use of the material that constitutes the Autoconf Macro.
 226 #
 227 #   This special exception to the GPL applies to versions of the Autoconf
 228 #   Macro released by the Autoconf Archive. When you make and distribute a
 229 #   modified version of the Autoconf Macro, you may extend this special
 230 #   exception to the GPL to apply to your modified version as well.
 231
 232 AC_DEFUN([AX_CFLAGS_GCC_OPTION_OLD], [dnl
 233 AS_VAR_PUSHDEF([FLAGS],[CFLAGS])dnl
 234 AS_VAR_PUSHDEF([VAR],[ax_cv_cflags_gcc_option_$2])dnl
 235 AC_CACHE_CHECK([m4_ifval($1,$1,FLAGS) for gcc m4_ifval($2,$2,-option)],
 236 VAR,[VAR="no, unknown"
 237  AC_LANG_SAVE
 238  AC_LANG_C
 239  ac_save_[]FLAGS="$[]FLAGS"
 240 for ac_arg dnl
 241 in "-pedantic -Werror % m4_ifval($2,$2,-option)"  dnl   GCC
 242    "-pedantic % m4_ifval($2,$2,-option) %% no, obsolete"  dnl new GCC
 243    #
 244 do FLAGS="$ac_save_[]FLAGS "`echo $ac_arg | sed -e 's,%%.*,,' -e 's,%,,'`
 245    AC_TRY_COMPILE([],[return 0;],
 246    [VAR=`echo $ac_arg | sed -e 's,.*% *,,'` ; break])
 247 done
 248  FLAGS="$ac_save_[]FLAGS"
 249  AC_LANG_RESTORE
 250 ])
 251 case ".$VAR" in
 252      .ok|.ok,*) m4_ifvaln($3,$3) ;;
 253    .|.no|.no,*) m4_ifvaln($4,$4) ;;
 254    *) m4_ifvaln($3,$3,[
 255    if echo " $[]m4_ifval($1,$1,FLAGS) " | grep " $VAR " 2>&1 >/dev/null
 256    then AC_RUN_LOG([: m4_ifval($1,$1,FLAGS) does contain $VAR])
 257    else AC_RUN_LOG([: m4_ifval($1,$1,FLAGS)="$m4_ifval($1,$1,FLAGS) $VAR"])
 258                       m4_ifval($1,$1,FLAGS)="$m4_ifval($1,$1,FLAGS) $VAR"
 259    fi ]) ;;
 260 esac
 261 AS_VAR_POPDEF([VAR])dnl
 262 AS_VAR_POPDEF([FLAGS])dnl
 263 ])
 264
 265
 266 dnl the only difference - the LANG selection... and the default FLAGS
 267
 268 AC_DEFUN([AX_CXXFLAGS_GCC_OPTION_OLD], [dnl
 269 AS_VAR_PUSHDEF([FLAGS],[CXXFLAGS])dnl
 270 AS_VAR_PUSHDEF([VAR],[ax_cv_cxxflags_gcc_option_$2])dnl
 271 AC_CACHE_CHECK([m4_ifval($1,$1,FLAGS) for gcc m4_ifval($2,$2,-option)],
 272 VAR,[VAR="no, unknown"
 273  AC_LANG_SAVE
 274  AC_LANG_CPLUSPLUS
 275  ac_save_[]FLAGS="$[]FLAGS"
 276 for ac_arg dnl
 277 in "-pedantic -Werror % m4_ifval($2,$2,-option)"  dnl   GCC
 278    "-pedantic % m4_ifval($2,$2,-option) %% no, obsolete"  dnl new GCC
 279    #
 280 do FLAGS="$ac_save_[]FLAGS "`echo $ac_arg | sed -e 's,%%.*,,' -e 's,%,,'`
 281    AC_TRY_COMPILE([],[return 0;],
 282    [VAR=`echo $ac_arg | sed -e 's,.*% *,,'` ; break])
 283 done
 284  FLAGS="$ac_save_[]FLAGS"
 285  AC_LANG_RESTORE
 286 ])
 287 case ".$VAR" in
 288      .ok|.ok,*) m4_ifvaln($3,$3) ;;
 289    .|.no|.no,*) m4_ifvaln($4,$4) ;;
 290    *) m4_ifvaln($3,$3,[
 291    if echo " $[]m4_ifval($1,$1,FLAGS) " | grep " $VAR " 2>&1 >/dev/null
 292    then AC_RUN_LOG([: m4_ifval($1,$1,FLAGS) does contain $VAR])
 293    else AC_RUN_LOG([: m4_ifval($1,$1,FLAGS)="$m4_ifval($1,$1,FLAGS) $VAR"])
 294                       m4_ifval($1,$1,FLAGS)="$m4_ifval($1,$1,FLAGS) $VAR"
 295    fi ]) ;;
 296 esac
 297 AS_VAR_POPDEF([VAR])dnl
 298 AS_VAR_POPDEF([FLAGS])dnl
 299 ])
 300
 301 dnl -------------------------------------------------------------------------
 302
 303 AC_DEFUN([AX_CFLAGS_GCC_OPTION_NEW], [dnl
 304 AS_VAR_PUSHDEF([FLAGS],[CFLAGS])dnl
 305 AS_VAR_PUSHDEF([VAR],[ax_cv_cflags_gcc_option_$1])dnl
 306 AC_CACHE_CHECK([m4_ifval($2,$2,FLAGS) for gcc m4_ifval($1,$1,-option)],
 307 VAR,[VAR="no, unknown"
 308  AC_LANG_SAVE
 309  AC_LANG_C
 310  ac_save_[]FLAGS="$[]FLAGS"
 311 for ac_arg dnl
 312 in "-pedantic -Werror % m4_ifval($1,$1,-option)"  dnl   GCC
 313    "-pedantic % m4_ifval($1,$1,-option) %% no, obsolete"  dnl new GCC
 314    #
 315 do FLAGS="$ac_save_[]FLAGS "`echo $ac_arg | sed -e 's,%%.*,,' -e 's,%,,'`
 316    AC_TRY_COMPILE([],[return 0;],
 317    [VAR=`echo $ac_arg | sed -e 's,.*% *,,'` ; break])
 318 done
 319  FLAGS="$ac_save_[]FLAGS"
 320  AC_LANG_RESTORE
 321 ])
 322 case ".$VAR" in
 323      .ok|.ok,*) m4_ifvaln($3,$3) ;;
 324    .|.no|.no,*) m4_ifvaln($4,$4) ;;
 325    *) m4_ifvaln($3,$3,[
 326    if echo " $[]m4_ifval($2,$2,FLAGS) " | grep " $VAR " 2>&1 >/dev/null
 327    then AC_RUN_LOG([: m4_ifval($2,$2,FLAGS) does contain $VAR])
 328    else AC_RUN_LOG([: m4_ifval($2,$2,FLAGS)="$m4_ifval($2,$2,FLAGS) $VAR"])
 329                       m4_ifval($2,$2,FLAGS)="$m4_ifval($2,$2,FLAGS) $VAR"
 330    fi ]) ;;
 331 esac
 332 AS_VAR_POPDEF([VAR])dnl
 333 AS_VAR_POPDEF([FLAGS])dnl
 334 ])
 335
 336
 337 dnl the only difference - the LANG selection... and the default FLAGS
 338
 339 AC_DEFUN([AX_CXXFLAGS_GCC_OPTION_NEW], [dnl
 340 AS_VAR_PUSHDEF([FLAGS],[CXXFLAGS])dnl
 341 AS_VAR_PUSHDEF([VAR],[ax_cv_cxxflags_gcc_option_$1])dnl
 342 AC_CACHE_CHECK([m4_ifval($2,$2,FLAGS) for gcc m4_ifval($1,$1,-option)],
 343 VAR,[VAR="no, unknown"
 344  AC_LANG_SAVE
 345  AC_LANG_CPLUSPLUS
 346  ac_save_[]FLAGS="$[]FLAGS"
 347 for ac_arg dnl
 348 in "-pedantic -Werror % m4_ifval($1,$1,-option)"  dnl   GCC
 349    "-pedantic % m4_ifval($1,$1,-option) %% no, obsolete"  dnl new GCC
 350    #
 351 do FLAGS="$ac_save_[]FLAGS "`echo $ac_arg | sed -e 's,%%.*,,' -e 's,%,,'`
 352    AC_TRY_COMPILE([],[return 0;],
 353    [VAR=`echo $ac_arg | sed -e 's,.*% *,,'` ; break])
 354 done
 355  FLAGS="$ac_save_[]FLAGS"
 356  AC_LANG_RESTORE
 357 ])
 358 case ".$VAR" in
 359      .ok|.ok,*) m4_ifvaln($3,$3) ;;
 360    .|.no|.no,*) m4_ifvaln($4,$4) ;;
 361    *) m4_ifvaln($3,$3,[
 362    if echo " $[]m4_ifval($2,$2,FLAGS) " | grep " $VAR " 2>&1 >/dev/null
 363    then AC_RUN_LOG([: m4_ifval($2,$2,FLAGS) does contain $VAR])
 364    else AC_RUN_LOG([: m4_ifval($2,$2,FLAGS)="$m4_ifval($2,$2,FLAGS) $VAR"])
 365                       m4_ifval($2,$2,FLAGS)="$m4_ifval($2,$2,FLAGS) $VAR"
 366    fi ]) ;;
 367 esac
 368 AS_VAR_POPDEF([VAR])dnl
 369 AS_VAR_POPDEF([FLAGS])dnl
 370 ])
 371
 372 AC_DEFUN([AX_CFLAGS_GCC_OPTION],[ifelse(m4_bregexp([$2],[-]),-1,
 373 [AX_CFLAGS_GCC_OPTION_NEW($@)],[AX_CFLAGS_GCC_OPTION_OLD($@)])])
 374
 375 AC_DEFUN([AX_CXXFLAGS_GCC_OPTION],[ifelse(m4_bregexp([$2],[-]),-1,
 376 [AX_CXXFLAGS_GCC_OPTION_NEW($@)],[AX_CXXFLAGS_GCC_OPTION_OLD($@)])])